.( fendo.addon.source_code.common.fs) cr

forth_definitions

require galope/package.fs \ `package`, `private`, `public`, `end-package`

require galope/replaced.fs \ `replaced`

require galope/s-constant.fs \ `sconstant`

require galope/sourcepath.fs \ `sourcepath`

fendo_definitions

package fendo.addon.source_code.common

public

false value highlight?

\ flag to switch the code highlighting on and off

$variable programming_language$

\ same values than Vim's `filetype`

$variable previous_programming_language$

\ copy used by some addons

: programming_language! ( ca len -- )

programming_language$ $! ;

\ Set the Vim's filetype for syntax highlighting.

: programming_language@ ( -- ca len )

programming_language$ $@ ;

\ Fetch the Vim's filetype for syntax highlighting.

: programming_language? ( -- f )

programming_language$ $@len 0<> ;

\ Has a programming language been set?

: programming_language?! ( ca len -- )

programming_language? if 2drop else programming_language! then ;

\ Set the Vim's filetype for syntax highlighting, if not already set.

$variable source_code$

: escaped_source_code ( ca len -- ca' len' )

highlight? 0= if s" &lt;" s" <" replaced then ;

\ Escape special chars in source code.

\ Used by the wiki markup module and the source code addon.

: append_source_code_line ( ca len -- )

highlight? 0= if escaped_source_code then

source_code$ $+! s\" \n" source_code$ $+! ;

: new_source_code ( -- )

0 source_code$ $!len ;

: source_code@ ( -- ca len )

source_code$ $@ ;

private

s" ./cache/addons/source_code/" sconstant cache_dir$ \ XXX TODO unused

s" /tmp/fendo_addon.source_code.txt" sconstant input_file$

s" .xhtml" sconstant output_file_extension$

input_file$ output_file_extension$ s+ sconstant output_file$

public

: base_highlight_command$ ( -- ca len )

s" nvim -e -f " ;

s" fendo.addon.source_code.vim " sconstant vim_addon$

sourcepath vim_addon$ s+ sconstant vim_program$

private

: program+ ( ca len -- ca' len' )

s" -S " s+ vim_program$ s+ ;

\ Add the Vim program parameter to the Vim invocation command.

: parameters+ ( ca len -- ca' len' )

s\" -b -c \"set filetype=" s+ programming_language$ $@ s+ s\" \" " s+ ;

\ Add the required parameters to the Vim invocation command.

\ These parameters must be before the Vim program

\ and the source file in the command.

\ The binary option (-b) is required to make the

\ charset translations to work fine.

: highlighting_command$ ( -- ca len )

base_highlight_command$ parameters+ program+ input_file$ s+ ;

\ Return the complete highlighting command,

\ ready to be executed by the shell.

\ The command calls Vim in execution mode, this way:

\ vim -e -f -b -c "set filetype=PROGRAMMING_LANGUAGE"

\ -S ~/forth/fendo/fendo.addon.source_code.vim /tmp/fendo_addon.source_code.txt

: >input_file ( ca len -- )

input_file$ w/o create-file throw

dup >r write-file throw r> close-file throw ;

\ Save the given source code to the file that Vim will load as input.

\ ca len = plain source code

: <output_file ( -- ca len )

output_file$ slurp-file ;

\ Get the content of the file that Vim created as output.

\ ca len = source code highlighted with <span> XHTML tags

: (highlighted) ( ca1 len1 -- ca2 len2 )

>input_file highlighting_command$ system

$? abort" The system highlighting command failed"

<output_file ;

\ Highlight the given source code.

\ ca1 len1 = plain source code

\ ca2 len2 = source code highlighted with <span> XHTML tags

public

: highlighted ( ca1 len1 -- ca1 len1 | ca2 len2 )

highlight? if (highlighted) then ;

\ Highlight the given source code, if needed.

\ ca1 len1 = plain source code

\ ca2 len2 = source code highlighted with <span> XHTML tags

defer source_code_pretranslated ( ca len -- ca' len' )

\ Translate the source code before the highlighting.

\ This must be vectored by a specific addon.

\ This is used to translate 8-bit chars to UTF-8 chars;

\ otherwise the code of those chars would be converted

\ to text by the highlighting.

defer source_code_posttranslated ( ca len -- ca' len' )

\ Translate the source code after the highlighting.

\ This must be vectored by a specific addon.

\ This is used to translate strings to HTML entities or tags;

\ otherwise the highlighting would ruin them.

: no_source_code_translation ( -- )

['] noop dup

is source_code_pretranslated

is source_code_posttranslated ;

\ Deactivate the source code translations.

no_source_code_translation

: source_code_finished ( -- )

s" " programming_language! no_source_code_translation ;

\ Reset default values about the source code.

end-package

.( fendo.addon.source_code.common.fs compiled) cr

\

\

\

\

\

\

\

\

\

\

\

\

\

\

\

\

\

\

\