.( fendo.addon.linked_file_size.fs) cr

1024 constant KiB

KiB dup * constant MiB

: >linked_file_size ( n -- ca len )

s>d <# # # '.' hold #s #> ;

: echo_linked_file_size_MiB ( n -- )

100 * MiB / >linked_file_size echo s" MiB" _echo ;

: echo_linked_file_size_KiB ( n -- )

100 * KiB / >linked_file_size echo s" KiB" _echo ;

: echo_linked_file_size_B ( n -- )

echo. s" B" _echo ;

: echo_linked_file_size ( n -- )

dup MiB >= if echo_linked_file_size_MiB exit then

dup KiB >= if echo_linked_file_size_KiB exit then

echo_linked_file_size_B ;

: (linked_file_size) ( -- )

s" (" _echo

last_href$ $@ -file:// file>local

slurp-file nip echo_linked_file_size

s" )" echo ;

: linked_file_size ( -- )

file_link? if (linked_file_size) then ;

' linked_file_size is link_text_suffix

\ Set the hook.

\ doc{

\

\ linked_file_size ( -- )

\

\ An alternative action for `link_text_suffix`. It adds the file

\ size to file links.

\

\ Usage example (note this is already done when the addon of

\ ``linked_file_size`` is loaded):

\ ----

\ ' linked_file_size is link_text_suffix

\ ----

\ }doc

.( fendo.addon.linked_file_size.fs compiled) cr