ion/build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:+'
    }
}

apply plugin: 'com.android.library'

repositories {
    mavenCentral()
}

dependencies {
    compile 'com.android.support:support-v4:+'
    compile project(':AndroidAsync:AndroidAsync')
    compile 'com.google.code.gson:gson:2.3'
}

android {
    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'

            java {
                srcDir 'src/'
            }
        }
        androidTest.java.srcDirs=['test/src/']
        androidTest.res.srcDirs=['test/res/']
        androidTest.assets.srcDirs=['test/assets/']
    }

    lintOptions {
        abortOnError false
    }

    defaultConfig {
        targetSdkVersion 21
        minSdkVersion 9
    }

    compileSdkVersion 21
    buildToolsVersion '21.1.2'
}

// upload to maven task
if (System.getenv().I_AM_KOUSH == 'true') {
    apply from: 'https://raw.githubusercontent.com/koush/mvn-repo/master/maven.gradle'

    apply plugin: 'maven'
    apply plugin: 'signing'

    afterEvaluate { project ->
        uploadArchives {
            repositories {
                mavenDeployer {
                    pom*.whenConfigured { pom ->
                        pom.dependencies.removeAll { dep -> dep.artifactId == 'support-v4' }
                    }
                }
            }
        }
    }
}