![](https://help.apple.com/assets/6467B9B3CF36103D3A318861/6467B9B8CF36103D3A318879/vi_VN/784be3dfed809d4b6bb7cc427d8c5f01.png)
COUNTIFS
Hàm COUNTIFS trả về số lượng ô trong một hoặc nhiều tập hợp thỏa mãn các điều kiện cho trước (một điều kiện trên một tập hợp).
COUNTIFS(giá trị kiểm tra; điều kiện; giá trị kiểm tra...; điều kiện...)
giá trị kiểm tra: Một tập hợp chứa các giá trị sẽ được kiểm tra. giá trị kiểm tra có thể chứa bất kỳ giá trị nào.
điều kiện: Một biểu thức so sánh hoặc kiểm tra các giá trị và kết quả trong giá trị lô-gic TRUE hoặc FALSE. điều kiện có thể bao gồm các toán tử so sánh, hằng số, toán tử ghép nối và, tham chiếu và ký tự đại diện. Bạn có thể sử dụng ký tự đại diện để khớp với bất kỳ ký tự duy nhất nào hoặc nhiều ký tự trong biểu thức. Bạn có thể sử dụng dấu ? (dấu hỏi chấm) để biểu thị một ký tự, dấu * (dấu hoa thị) để biểu thị nhiều ký tự, và dấu ~ (dấu ngã) để biểu thị rằng ký tự tiếp sau đó cần phải khớp, chứ không phải được dùng làm ký tự đại diện. điều kiện cũng có thể chứa một hàm REGEX thay vì ký tự đại diện.
giá trị kiểm tra…: Tùy ý bao gồm một hoặc nhiều tập hợp chứa các giá trị sẽ được kiểm tra. Mỗi tập hợp giá trị kiểm tra phải được theo sau bởi biểu thức điều kiện. Mẫu giá trị kiểm tra, điều kiện này có thể được lặp lại nhiều lần nếu cần.
điều kiện…: Nếu tập hợp tùy chọn của giá trị kiểm tra được bao gồm, điều kiện… là một biểu thức bổ sung dẫn đến lô-gic TRUE hoặc FALSE. Phải có một biểu thức điều kiện theo sau mỗi tập hợp giá trị kiểm tra; do đó, số các đối số của hàm này luôn là số chẵn.
Ghi chú
Mỗi giá trị trong giá trị kiểm tra được so sánh với điều kiện tương ứng. Nếu giá trị tương ứng trong mỗi tập hợp đáp ứng kiểm tra điều kiện tương ứng, tổng số tăng thêm 1.
Ví dụ |
---|
Cho bảng sau: |
A | B | C | D | |
---|---|---|---|---|
1 | Tuổi | Giới tính | Tình trạng | Lương |
2 | 35 | M | M | 71.000 |
3 | 27 | F | M | 81.000 |
4 | 42 | M | M | 86.000 |
5 | 51 | M | S | 66.000 |
6 | 28 | M | S | 52.000 |
7 | 49 | F | S | 62.000 |
8 | 63 | F | M | 89.000 |
9 | 22 | M | M | 34.000 |
10 | 29 | F | S | 42.000 |
11 | 35 | F | M | 56.000 |
12 | 33 | M | S | 62.000 |
13 | 61 | M | M | 91.000 |
=COUNTIFS(A2:A13; "<40"; B2:B13; "=M") trả về 4, số lượng nam giới (được biểu thị bằng "M" trong cột B) dưới 40 tuổi. =COUNTIFS(A2:A13; "<>35"; B2:B13; "=M") trả về 6, số lượng nam giới (được biểu thị bằng "M" trong cột B) không phải 35 tuổi. Bạn cũng có thể sử dụng toán tử ≠. =COUNTIFS(A2:A13; "<40"; B2:B13; "=M"; C2:C13; "=S") trả về 2, số lượng nam giới độc thân (được biểu thị bằng "S" trong cột C) và dưới 40 tuổi. =COUNTIFS(A2:A13; "<40"; B2:B13; "=M"; C2:C13; "=M") trả về 2, số lượng nam giới đã kết hôn (được biểu thị bằng "M" trong cột C) và dưới 40 tuổi. =COUNTIFS(A2:A13; "<40"; B2:B13; "=F") trả về 3, số lượng nữ giới (được biểu thị bằng "F" trong cột B) dưới 40 tuổi. |
Ví dụ sử dụng REGEX |
---|
Cho bảng sau: |
A | B | |
---|---|---|
1 | 45 | marina@example.com |
2 | 41 | Aaron |
3 | 29 | michael@example.com |
4 | 64 | katrina@example.com |
5 | 12 | Sarah |
= COUNTIFS(B1:B5; REGEX("([A-Z0-9a-z._%+-]+)@([A-Za-z0-9.-]+\.[A-Za-z]{2,4})"); A1:A5; ">10") trả về số lượng ô trong A1:A5 lớn hơn 10 và trong đó ô tương ứng trong B1:B5 chứa một địa chỉ email. |