(defun counsel-projectile-rg (&optional options)
  "Search the current project with rg.

OPTIONS, if non-nil, is a string containing additional options to
be passed to rg. It is read from the minibuffer if the function
is called with a prefix argument."
  (interactive)
  (if (and (eq projectile-require-project-root 'prompt)
           (not (projectile-project-p)))
      (counsel-projectile-rg-action-switch-project)
    (let* ((ivy--actions-list (copy-sequence ivy--actions-list))
           (path
            (mapconcat 'shell-quote-argument
                       (or (projectile-normalise-paths
                            (car (projectile-parse-dirconfig-file)))
                           '("."))
                       " "))
           (ignored
            (mapconcat (lambda (i)
                         (concat "--glob !" (shell-quote-argument i)))
                       (append
                        (projectile--globally-ignored-file-suffixes-glob)
                        (projectile-ignored-files-rel)
                        (projectile-ignored-directories-rel))
                       " "))
           (counsel-rg-base-command
            (format (counsel-projectile--string-trim-right counsel-rg-base-command " \\.")
                    (concat ignored " %s " path))))
      (ivy-add-actions
       'counsel-rg
       counsel-projectile-rg-extra-actions)
      (counsel-rg (eval counsel-projectile-rg-initial-input)
                  (projectile-project-root)
                  options
                  (projectile-prepend-project-name
                   (concat (car (split-string counsel-rg-base-command)) ": "))))))