Install bash completion script automatically

digital-asset · mergify · Jan 6, 2020 · Jan 3, 2020 · Jan 3, 2020 · Jan 3, 2020
commit 27e9963fb43f1bbc6e094a1b04d71c3944df2828
diff --git a/daml-assistant/exe/DA/Daml/Assistant.hs b/daml-assistant/exe/DA/Daml/Assistant.hs
@@ -111,6 +111,7 @@ autoInstall env@Env{..} = do
                 , iActivate = ActivateInstall False
                 , iForce = ForceInstall False
                 , iSetPath = SetPath True
+                , iBashCompletions = BashCompletions Auto
                 }
             installEnv = InstallEnv
                 { options = options

diff --git a/daml-assistant/src/DA/Daml/Assistant/Command.hs b/daml-assistant/src/DA/Daml/Assistant/Command.hs
@@ -89,6 +89,7 @@ installParser = InstallOptions
     <*> iflag ForceInstall "force" (short 'f') "Overwrite existing installation"
     <*> iflag QuietInstall "quiet" (short 'q') "Don't display installation messages"
     <*> fmap SetPath (flagYesNoAuto "set-path" True "Adjust PATH automatically. This option only has an effect on Windows." idm)
+    <*> fmap BashCompletions (flagYesNoAuto' "bash-completions" "Install bash completions for DAML assistant. Default is yes for linux and mac, no for windows." idm)
     where
         iflag p name opts desc = fmap p (switch (long name <> help desc <> opts))
 

diff --git a/daml-assistant/src/DA/Daml/Assistant/Install.hs b/daml-assistant/src/DA/Daml/Assistant/Install.hs
@@ -15,6 +15,7 @@ import DA.Daml.Assistant.Types
 import DA.Daml.Assistant.Util
 import qualified DA.Daml.Assistant.Install.Github as Github
 import DA.Daml.Assistant.Install.Path
+import DA.Daml.Assistant.Install.BashCompletion
 import DA.Daml.Project.Consts
 import DA.Daml.Project.Config
 import DA.Daml.Project.Util
@@ -190,6 +191,7 @@ activateDaml env@InstallEnv{..} targetPath = do
             else createSymbolicLink damlBinarySourcePath damlBinaryTargetPath
 
     updatePath options (\s -> unlessQuiet env (output s)) damlBinaryTargetDir
+    installBashCompletions options damlPath (\s -> unlessQuiet env (output s))
 
 data WalkCallbacks = WalkCallbacks
     { walkOnFile :: FilePath -> IO ()

diff --git a/daml-assistant/src/DA/Daml/Assistant/Install/BashCompletion.hs b/daml-assistant/src/DA/Daml/Assistant/Install/BashCompletion.hs
@@ -0,0 +1,55 @@
+
+-- | Installation of bash completions. These are installed in
+-- /usr/local/etc/bash_completion.d (on Mac) or /etc/bash_completion.d (on Linux).
+-- These are not installed on Windows by default.
+module DA.Daml.Assistant.Install.BashCompletion
+    ( installBashCompletions
+    ) where
+
+import DA.Daml.Assistant.Types
+
+import qualified Data.ByteString.Lazy as BSL
+import Control.Monad.Extra (when, unlessM)
+import System.Directory (doesDirectoryExist, doesFileExist)
+import System.FilePath ((</>))
+import System.Info.Extra (isMac, isWindows)
+import System.Process.Typed (proc, readProcessStdout_)
+
+installBashCompletions :: InstallOptions -> DamlPath -> (String -> IO ()) -> IO ()
+installBashCompletions options damlPath output =
+    when (shouldInstallBashCompletions options) $
+        doInstallBashCompletions damlPath output
+
+shouldInstallBashCompletions :: InstallOptions -> Bool
+shouldInstallBashCompletions options =
+    case iBashCompletions options of
+        BashCompletions Yes -> True
+        BashCompletions No -> False
+        BashCompletions Auto -> not isWindows
+
+doInstallBashCompletions :: DamlPath -> (String -> IO ()) -> IO ()
+doInstallBashCompletions damlPath output = do
+    dirExists <- doesDirectoryExist bashCompletionDir
+    if dirExists
+        then do
+            unlessM (doesFileExist bashCompletionScript) $ do
+                completionScript <- getCompletionScript damlPath
+                BSL.writeFile bashCompletionScript completionScript
+                output ("Bash completions for DAML assistant installed in " <> bashCompletionDir)
+        else output ("Bash completions for DAML assistant not installed: " <> bashCompletionDir <> " does not exist")
+
+getCompletionScript :: DamlPath -> IO BSL.ByteString
+getCompletionScript damlPath = do
+    let assistant = assistantPath damlPath
+    readProcessStdout_ (proc assistant ["--bash-completion-script", assistant])
+
+assistantPath :: DamlPath -> FilePath
+assistantPath (DamlPath p) = p </> "bin" </> "daml"
+
+bashCompletionDir :: FilePath
+bashCompletionDir
+    | isMac = "/usr/local/etc/bash_completion.d"
+    | otherwise = "/etc/bash_completion.d"
+
+bashCompletionScript :: FilePath
+bashCompletionScript = bashCompletionDir </> "daml"
diff --git a/daml-assistant/src/DA/Daml/Assistant/Types.hs b/daml-assistant/src/DA/Daml/Assistant/Types.hs
@@ -88,6 +88,7 @@ data InstallOptions = InstallOptions
     , iForce :: ForceInstall -- ^ force reinstall if already installed
     , iQuiet :: QuietInstall -- ^ don't print messages
     , iSetPath :: SetPath -- ^ set the user's PATH (on Windows)
+    , iBashCompletions :: BashCompletions -- ^ install bash completions for the daml assistant
     } deriving (Eq, Show)
 
 -- | An install URL is a fully qualified HTTP[S] URL to an SDK release tarball. For example:
@@ -102,5 +103,4 @@ newtype QuietInstall = QuietInstall { unQuietInstall :: Bool } deriving (Eq, Sho
 newtype ActivateInstall = ActivateInstall { unActivateInstall :: Bool } deriving (Eq, Show)
 newtype SetPath = SetPath Bool deriving (Eq, Show)
 newtype InstallAssistant = InstallAssistant { unwrapInstallAssistant :: YesNoAuto } deriving (Eq, Show)
-
-
+newtype BashCompletions = BashCompletions { unwrapBashCompletions :: YesNoAuto } deriving (Eq, Show)
diff --git a/daml-assistant/test/DA/Daml/Assistant/Tests.hs b/daml-assistant/test/DA/Daml/Assistant/Tests.hs
@@ -378,6 +378,7 @@ testInstall = Tasty.testGroup "DA.Daml.Assistant.Install"
                     , iQuiet = QuietInstall True
                     , iForce = ForceInstall False
                     , iSetPath = SetPath False
+                    , iBashCompletions = BashCompletions No
                     }
 
             setCurrentDirectory base
@@ -411,6 +412,7 @@ testInstallUnix = Tasty.testGroup "unix-specific tests"
                           , iQuiet = QuietInstall True
                           , iForce = ForceInstall False
                           , iSetPath = SetPath False
+                          , iBashCompletions = BashCompletions No
                           }
 
                   setCurrentDirectory base
@@ -439,6 +441,7 @@ testInstallUnix = Tasty.testGroup "unix-specific tests"
                     , iQuiet = QuietInstall True
                     , iForce = ForceInstall False
                     , iSetPath = SetPath False
+                    , iBashCompletions = BashCompletions No
                     }
 
             setCurrentDirectory base
@@ -467,6 +470,7 @@ testInstallUnix = Tasty.testGroup "unix-specific tests"
                     , iQuiet = QuietInstall True
                     , iForce = ForceInstall False
                     , iSetPath = SetPath False
+                    , iBashCompletions = BashCompletions No
                     }
 
             setCurrentDirectory base