terraform {

  backend "s3" {}

  required_version = ">= 1.0.0"

  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = ">= 5.76"
    }
    docker = {
      source  = "kreuzwerker/docker"
      version = ">= 3.0.2"
    }
  }
}

variable "name" {
  type        = string
  description = "name for the resources"
}

variable "environment" {
  type        = string
  description = "environment for the resources"
}

variable "image_tag" {
  type        = string
  description = "container image tag"
}

variable "project" {
  type        = string
  description = "project name in monorepo"
}

locals {
  ns = "${var.name}-${var.environment}"
}

data "aws_region" "current" {}

data "aws_caller_identity" "current" {}

data "aws_ecr_authorization_token" "token" {}

provider "aws" {}

provider "docker" {
  registry_auth {
    address  = format("%v.dkr.ecr.%v.amazonaws.com", data.aws_caller_identity.current.account_id, data.aws_region.current.name)
    username = data.aws_ecr_authorization_token.token.user_name
    password = data.aws_ecr_authorization_token.token.password
  }
}

module "docker_image" {
  source = "terraform-aws-modules/lambda/aws//modules/docker-build"

  docker_file_path = "Dockerfile.frontend"
  create_ecr_repo  = true
  ecr_repo         = trim(replace(local.ns, "--" , "-"), "-") # replace double dash with simple dash and trim ending dash
  image_tag        = var.image_tag
  source_path      = "../../"
  build_args = {
    NODE_VERSION    = "20"
    PROJECT         =  var.project
    PORT            =  "8080"
  }
}

module "lambda_function_from_container_image" {
  source = "terraform-aws-modules/lambda/aws"

  function_name              = local.ns
  description                = "Ephemeral preview environment for: ${local.ns}"
  create_package             = false
  package_type               = "Image"
  image_uri                  = module.docker_image.image_uri
  architectures              = ["x86_64"]
  create_lambda_function_url = true
  timeout                    = 30
  memory_size                = 1024
}

output "endpoint_url" {
  value = module.lambda_function_from_container_image.lambda_function_url
}